Quick Debug Beta 1

<!-- #include file="debug.asp" -->
<%
Dim strA
Dim strB

strA = 7
' strX = 6
strB = 3
strC = "abc"

Call QDebug()

%>

<!-- #include file="_fn_file.asp" -->
<%
Sub QDebug()

  On Error Resume Next

  Dim strVPath_ThisFile
  Dim strPPath_ThisFile
  Dim strSourceCode
  Dim objRegExp
  Dim colMatches

  strVPath_ThisFile = Request.ServerVariables("SCRIPT_NAME")
  strPPath_ThisFile = Server.MapPath(strVPath_ThisFile)

  strSourceCode = File_ContentsToString(strPPath_ThisFile)

  Set objRegExp = New RegExp
  objRegExp.MultiLine = True
  objRegExp.Global = True
  objRegExp.Pattern = "^[ \f\t\v]*?([a-zA-Z][^'\. \f\t\v]*?)[ \f\t\v]="
  Set colMatches = objRegExp.Execute(strSourceCode)

  Response.Write("<table border=""1"">")

  For Each objItem In colMatches
    strVariableName = objItem.Submatches(0)
    strVariableType = TypeName(Eval(strVariableName))
    strVariableValue = Eval(strVariableName)
    Response.Write("<tr><td>" & Server.HTMLEncode(strVariableType) & "</td><td>" &   Server.HTMLEncode(strVariableName) & "</td><td>" & Server.HTMLEncode(strVariableValue) & "</td></tr>")
  Next

  Response.Write("</table>")

  Set objRegExp = Nothing

End Sub
%>